dd2c7e902a
cac13f1 Add CMakePackageConfigHelpers as a backported module from 2.8.10 44e17a5 Update help 92f9405 Add FindDirectShow from VRPN a93bf46 Update FindVRPN edf459d clean up some modules 0bf8b53 Update documentation/help 900ae37 Improvements to findcppdom bcdd5ed Adrienne timecode generator finder fc14864 IDLJ finder/script 5fa91d4 Finder for windows/platform SDK 835a160 Add module to find perl modules: pass them as components 7dc76c3 cleanup 38e2a0d Create a doc_open target to open html docs e8de008 Improved directx finding 787900c Conditionally use libuuid for VPR22 1c73e35 Add a helper error message to findcppcheck. 9e8b357 Generate, rather than enumerate, juggler lib names. d42ae48 Add another compiler flag for warnings. 911f522 Just a little cleanup. a466ea5 Update help 30af184 Add two new scripts written for VR Juggler 09ccc48 Update VR Juggler finders for 3.0.1 f9a5b86 VR JuggLua is no longer unreleased research software - ditch the scary warning. 1adb75e Update GetGitRevisionDescription to handle new submodules a little better. 187b7b2 Add new FindViewPoint d1ec683 Enhance FindOpenHaptics to handle 3.1 de68fc0 Restore some tabs that went missing feb11f6 Improve GHOST finder. b922e06 Update help 7ff9c53 Run cmake-bulk-decrufter. 0873f79 Merge branch 'jscasallas/master' e2ec7cd Add helpful comment about use as submodule 2a42dc5 Simplify FindQVRPN. 8ddcb84 Windows compatibility for the pull request just merged 4fcc618 Merge pull request #6 from phire/cmake-modules fa1ef4c Add additional versions of cppdom and gmtl. 7db0714 Regenerate help 39c0f2f Add find directinput d2e2a74 Update copyright year 5c05172 Update module help 5b62638 Rename to UseMarkdown and add rename feature f92055a Add markdown scripts (finding and targets) 00cefbe GetGitRevisionDescription: Search parent dirs for .git/ 0fb259a New module: FindQVRPN.cmake 9616f6e Find jccl and vrjuggler plugins, and split between debug and release 4856978 Set WIIUSE_RUNTIME_LIBRARY in Wiiuse even not on Windows d94b209 make FindWinHID work on MinGW. 4c110cb Fix copy-pasteo in findcppunit 8be460a fix doc typo 6a78da3 Handle other compilers better by using compiler ID a90f87b Use compiler behavior, not identity, to decide what warning flags to use f03d7a8 Properly check the various arguments to cppcheck rather than assume based on a few tests. d3ffd8a get git revision more robustly 1fb0e41 update ghost fake stl to simplify header 6fbe007 No more checking the stdc++ version for openhaptics db11bb9 make sure we actually link against HDU/HLU nested targets! a6580e9 remove unused variables in test file f4a26c5 update copyright 16a6266 fix dcubed nested target ca5cd7a mark luac item as advanced f131cbe actually use the jttk root dir specified 501dbb2 improve dcubed include dirs ae8764f improve splitting osg plugins into debug and release git-subtree-dir: cmake git-subtree-split: cac13f1c3225555cec9ae06a1ba47baa8c90442a
93 lines
3.2 KiB
CMake
93 lines
3.2 KiB
CMake
# - try to find Java's IDLJ Interface Definition Language compiler.
|
|
#
|
|
# Ideally used with CMake 2.8.5 or newer for Java support using FindJava.cmake
|
|
# and UseJava.cmake
|
|
#
|
|
# Variables:
|
|
# Java_IDLJ_COMMAND, executable for idlj
|
|
# IDLJ_FOUND, If false, do not try to use this
|
|
#
|
|
# Function:
|
|
# java_idlj(varname idlfile [extra idlj args]) - Generates
|
|
# the Java source files from the IDL file you indicate, and
|
|
# appends filenames suitable to add to a add_jar() call to the
|
|
# variable you specified.
|
|
#
|
|
# Because the files generated from an IDL file are not entirely predictable,
|
|
# java_idlj runs idlj in the cmake step, rather than the build step, and triggers
|
|
# a CMake re-run when an idl file is modified. Already up-to-date generated source
|
|
# is not re-generated, however.
|
|
#
|
|
# Files are generated in a directory created specifically for
|
|
# the particular IDL file and the particular call, in the build directory -
|
|
# there should be no worries about overwriting files or picking up too much
|
|
# with the wildcard.
|
|
#
|
|
# You may wish to add the IDL file to your list of sources if you want it
|
|
# to appear in your IDE, but it is not necessary.
|
|
#
|
|
# Original Author:
|
|
# 2012 Ryan Pavlik <rpavlik@iastate.edu> <abiryan@ryand.net>
|
|
# http://academic.cleardefinition.com
|
|
# Iowa State University HCI Graduate Program/VRAC
|
|
#
|
|
# Copyright Iowa State University 2012.
|
|
# Distributed under the Boost Software License, Version 1.0.
|
|
# (See accompanying file LICENSE_1_0.txt or copy at
|
|
# http://www.boost.org/LICENSE_1_0.txt)
|
|
|
|
if(NOT JAVA_FOUND)
|
|
find_package(Java QUIET)
|
|
endif()
|
|
|
|
if(JAVA_FOUND)
|
|
get_filename_component(JAVA_BIN_DIR "${Java_JAVAC_EXECUTABLE}" PATH)
|
|
find_program(Java_IDLJ_COMMAND
|
|
idlj
|
|
HINTS
|
|
${JAVA_BIN_DIR}
|
|
)
|
|
endif()
|
|
|
|
# handle the QUIETLY and REQUIRED arguments and set xxx_FOUND to TRUE if
|
|
# all listed variables are TRUE
|
|
include(FindPackageHandleStandardArgs)
|
|
find_package_handle_standard_args(IDLJ
|
|
DEFAULT_MSG
|
|
Java_IDLJ_COMMAND
|
|
JAVA_FOUND)
|
|
|
|
if(IDLJ_FOUND)
|
|
function(java_idlj _varname _idlfile)
|
|
# Get some unique value we can use in a directory name
|
|
# TODO would be better to somehow munge the full path relative to CMAKE_CURRENT_SOURCE_DIR
|
|
# in case somebody has multiple idl files with the same name
|
|
get_filename_component(_idl_name "${_idlfile}" NAME_WE)
|
|
get_filename_component(_idl_abs "${_idlfile}" ABSOLUTE)
|
|
|
|
# Compute directory name and stamp filename
|
|
set(outdir "${CMAKE_CURRENT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/idlj/${_idl_name}.dir")
|
|
set(stampfile "${CMAKE_CURRENT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/idlj/${_idl_name}.stamp")
|
|
|
|
# Force re-cmake if idl file changes
|
|
configure_file("${_idl_abs}" "${stampfile}" COPY_ONLY)
|
|
|
|
if((NOT EXISTS "${outdir}") OR ("${_idl_abs}" IS_NEWER_THAN "${outdir}"))
|
|
file(REMOVE_RECURSE "${outdir}")
|
|
message(STATUS "Processing ${_idlfile} with Java's idlj")
|
|
execute_process(COMMAND
|
|
"${Java_IDLJ_COMMAND}" -fclient -fallTIE -td "${outdir}" ${ARGN} "${_idlfile}"
|
|
WORKING_DIRECTORY
|
|
"${CMAKE_CURRENT_SOURCE_DIR}")
|
|
endif()
|
|
file(GLOB_RECURSE _idl_output "${outdir}/*")
|
|
|
|
set(${_varname} ${_idl_output} PARENT_SCOPE)
|
|
|
|
# Clean up after ourselves on make clean
|
|
set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES "${outdir}" "${stampfile}")
|
|
endfunction()
|
|
endif()
|
|
|
|
mark_as_advanced(Java_IDLJ_COMMAND)
|